saiph: add strong scaling experiment

garlic/exp/saiph/strongScaling.nix

@@ -0,0 +1,71 @@
+{
+  stdenv
+, stdexp
+, bsc
+, targetMachine
+, stages
+}:
+
+with stdenv.lib;
+
+let
+  # Initial variable configuration
+  varConf = with bsc; {
+    nodes = [ 1 2 4 8 16 32 ];
+  };
+
+  # Generate the complete configuration for each unit
+  genConf = with bsc; c: targetMachine.config // rec {
+    expName = "saiph.strongScaling";
+    unitName = "${expName}.nodes-${toString nodes}-nb{y, z}=4";
+    inherit (targetMachine.config) hw;
+
+    # saiph options
+    nbx = 1;
+    nby = 4;
+    nbz = 4;
+    mpi = impi;
+    gitBranch = "garlic/tampi+isend+oss+task+simd";
+
+    # Repeat the execution of each unit 50 times
+    loops = 30;
+
+    # Resources
+    cachelineBytes = hw.cachelineBytes;
+    time = "02:00:00";
+    nodes = c.nodes;
+    qos = if (nodes>16)
+      then "bsc_cs"
+      else "debug";
+    ntasksPerNode = hw.socketsPerNode;
+    cpusPerTask = hw.cpusPerSocket;
+    jobName = "${unitName}-${gitBranch}";
+  };
+
+  # Compute the array of configurations
+  configs = stdexp.buildConfigs {
+    inherit varConf genConf;
+  };
+
+  exec = {nextStage, conf, ...}: with conf; stages.exec {
+    inherit nextStage;
+    env = ''
+      export NANOS6_REPORT_PREFIX="#"
+      export I_MPI_THREAD_SPLIT=1
+      export ASAN_SYMBOLIZER_PATH=${bsc.clangOmpss2Unwrapped}/bin/llvm-symbolizer
+    '';
+  };
+
+  program = {nextStage, conf, ...}: with conf;
+  let
+    customPkgs = stdexp.replaceMpi conf.mpi;
+  in
+    customPkgs.apps.saiph.override {
+      inherit nbx nby nbz mpi gitBranch cachelineBytes;
+    };
+
+  pipeline = stdexp.stdPipeline ++ [ exec program ];
+
+in
+ 
+  stdexp.genExperiment { inherit configs pipeline; }