bscpkgs/flake.nix

{
  inputs.nixpkgs.url = "nixpkgs";

  outputs = { self, nixpkgs, ...}:
  let
    system = "x86_64-linux";
    pkgs = import nixpkgs {
      inherit system;
      # For now we only support x86
      overlays = [ self.overlays.default ];
    };
  in
    {
      bscOverlay = import ./overlay.nix;
      overlays.default = self.bscOverlay;

      # full nixpkgs with our overlay applied
      legacyPackages.${system} = pkgs;

      # packages added by our overlay
      packages.${system} =
        let
          inherit (builtins) attrNames removeAttrs;
          inherit (nixpkgs.lib) flip filterAttrs getAttrs pipe isDerivation;
        in
          # extract the names of the packages from the overlay, then get the
          # actual packages from the full package set with the overlay applied
          pipe (self.overlays.default null null) [
            attrNames
            (flip getAttrs pkgs)
            (flip removeAttrs [ "bsc" ])
            (filterAttrs (_: isDerivation))
          ];
    };
}