Merge all branches

Even if we do an override to papi get the proper configure flags for
cross-compiling, the memory fences are not defined for risc-v:

mb.h:67:2: error: #error Need to define rmb for this architecture!

flake.nix

@@ -17,7 +17,7 @@
       legacyPackages.${system} = pkgs;
 
       hydraJobs = {
-        inherit (self.legacyPackages.${system}.bsc-ci) test pkgs;
+        inherit (self.legacyPackages.${system}.bsc-ci) test pkgs cross;
       };
 
       # propagate nixpkgs lib, so we can do bscpkgs.lib

overlay.nix

@@ -1,15 +1,22 @@
 final: /* Future last stage */
 prev:  /* Previous stage */
 
-with final.lib;
-
 let
-  callPackage = final.callPackage;
+  inherit (prev.lib) collect isDerivation mapAttrs filterAttrs;
+
+  inherit (final) callPackage;
 
   mkDeps = name: pkgs: final.runCommand name { }
     "printf '%s\n' ${toString (collect (x: x ? outPath) pkgs)} > $out";
 
-  bscPkgs = {
+  mkStrict = drv: if (isDerivation drv && drv ? overrideAttrs && !(drv ? strictDeps))
+    then drv.overrideAttrs { strictDeps = true; }
+    else drv;
+
+  bscPkgs = mapAttrs (_: mkStrict) {
+    aoccUnwrapped = callPackage ./pkgs/aocc/unwrapped.nix { };
+    aocc = callPackage ./pkgs/aocc/default.nix { };
+    stdenvAocc = final.overrideCC final.stdenv final.aocc;
     bench6 = callPackage ./pkgs/bench6/default.nix { };
     bigotes = callPackage ./pkgs/bigotes/default.nix { };
     clangOmpss2 = callPackage ./pkgs/llvm-ompss2/default.nix { };
@@ -17,9 +24,15 @@ let
     clangOmpss2Nodes = callPackage ./pkgs/llvm-ompss2/default.nix { ompss2rt = final.nodes; openmp = final.openmp; };
     clangOmpss2NodesOmpv = callPackage ./pkgs/llvm-ompss2/default.nix { ompss2rt = final.nodes; openmp = final.openmpv; };
     clangOmpss2Unwrapped = callPackage ./pkgs/llvm-ompss2/clang.nix { };
+    clsparse = callPackage ./pkgs/clsparse/package.nix { };
     #extrae = callPackage ./pkgs/extrae/default.nix { }; # Broken and outdated
     gpi-2 = callPackage ./pkgs/gpi-2/default.nix { };
+    intel-apt = callPackage ./pkgs/intel-oneapi/packages.nix { };
     intelPackages_2023 = callPackage ./pkgs/intel-oneapi/2023.nix { };
+    intelPackages_2024 = final.intel-apt.hpckit_2024;
+    intelPackages_2025 = final.intel-apt.hpckit_2025;
+    intelPackages = final.intelPackages_2025;
+    oneMath = callPackage ./pkgs/onemath/default.nix { };
     jemallocNanos6 = callPackage ./pkgs/nanos6/jemalloc.nix { };
     lmbench = callPackage ./pkgs/lmbench/default.nix { };
     mcxx = callPackage ./pkgs/mcxx/default.nix { };
@@ -46,7 +59,21 @@ let
     stdenvClangOmpss2NodesOmpv = final.stdenv.override { cc = final.clangOmpss2NodesOmpv; allowedRequisites = null; };
     tagaspi = callPackage ./pkgs/tagaspi/default.nix { };
     tampi = callPackage ./pkgs/tampi/default.nix { };
+    tacuda = callPackage ./pkgs/tacuda/default.nix { };
+    taopencl = callPackage ./pkgs/taopencl/default.nix { };
+    tasycl = callPackage ./pkgs/tasycl/default.nix { };
+    tasycl-acpp = callPackage ./pkgs/tasycl/default.nix { useIntel = false; };
     wxparaver = callPackage ./pkgs/paraver/default.nix { };
+
+    # Fix for RISC-V cross compilation
+    # TODO: remove once we update to 25.11
+    # https://github.com/NixOS/nixpkgs/commit/d9c222c81435b
+    prrte = prev.prrte.overrideAttrs (prevAttrs: {
+      configureFlags = (prevAttrs.configureFlags or []) ++ [
+        "--with-pmix=${prev.lib.getDev final.pmix}"
+        "--with-pmix-libdir=${prev.lib.getLib final.pmix}/lib"
+      ];
+    });
   };
 
 in bscPkgs // {
@@ -60,6 +87,8 @@ in bscPkgs // {
       #sigsegv = callPackage ./test/reproducers/sigsegv.nix { };
       hello-c = callPackage ./test/compilers/hello-c.nix { };
       hello-cpp = callPackage ./test/compilers/hello-cpp.nix { };
+      hello-sycl = callPackage ./test/compilers/hello-sycl.nix { };
+      hello-syclompss = callPackage ./test/compilers/icpx-ompss2.nix { };
       lto = callPackage ./test/compilers/lto.nix { };
       asan = callPackage ./test/compilers/asan.nix { };
       intel2023-icx-c   = hello-c.override   { stdenv = final.intelPackages_2023.stdenv; };
@@ -69,6 +98,15 @@ in bscPkgs // {
       intel2023-ifort   = callPackage ./test/compilers/hello-f.nix {
         stdenv = final.intelPackages_2023.stdenv-ifort;
       };
+
+      intel2024-icx-c   = hello-c.override   { stdenv = final.intelPackages_2024.stdenv; };
+      intel2025-icx-c   = hello-c.override   { stdenv = final.intelPackages_2025.stdenv; };
+      intel2024-icx-cpp = hello-cpp.override { stdenv = final.intelPackages_2024.stdenv; };
+      intel2025-icx-cpp = hello-cpp.override { stdenv = final.intelPackages_2025.stdenv; };
+      intel2023-sycl    = hello-sycl.override { intelPackages = final.intelPackages_2023; };
+      intel2024-sycl    = hello-sycl.override { intelPackages = final.intelPackages_2024; };
+      intel2025-sycl    = hello-sycl.override { intelPackages = final.intelPackages_2025; };
+
       clangOmpss2-lto   = lto.override       { stdenv = final.stdenvClangOmpss2Nanos6; };
       clangOmpss2-asan  = asan.override      { stdenv = final.stdenvClangOmpss2Nanos6; };
       clangOmpss2-task  = callPackage ./test/compilers/ompss2.nix {
@@ -96,6 +134,10 @@ in bscPkgs // {
     tests = final.runCommand "ci-tests" { }
       "printf '%s\n' ${toString (collect isDerivation final.bsc-ci.test)} > $out";
 
+    cross = prev.lib.genAttrs [ "riscv64" ] (target:
+      final.pkgsCross.${target}.bsc-ci.pkgs
+    );
+
     all = final.runCommand "ci-all" { }
     ''
       deps="${toString [ final.bsc-ci.pkgsList final.bsc-ci.tests ]}"

pkgs/aocc/default.nix

@@ -0,0 +1,16 @@
+{ wrapCCWith
+, aoccUnwrapped
+}:
+
+let
+  cc = aoccUnwrapped;
+in wrapCCWith {
+  inherit cc;
+
+  extraBuildCommands = ''
+    echo "-isystem ${cc}/include" >> $out/nix-support/cc-cflags
+
+    wrap aocc   $wrapper $ccPath/clang
+    wrap aocc++ $wrapper $ccPath/clang++
+  '';
+}

pkgs/aocc/unwrapped.nix

@@ -0,0 +1,51 @@
+{ lib
+, fetchurl
+, stdenv
+, autoPatchelfHook
+, rocmPackages
+, zlib
+, libffi
+, elfutils
+}:
+
+let
+  # in newer nixpkgs the runtime is hsakmt
+  rocmRuntime =
+    if rocmPackages ? hsakmt then
+      rocmPackages.hsakmt
+    else
+      rocmPackages.rocm-runtime;
+in
+stdenv.mkDerivation {
+  pname = "aocc-compiler";
+  version = "5.0.0";
+
+  src = fetchurl {
+    url = "https://download.amd.com/developer/eula/aocc/aocc-5-0/aocc-compiler-5.0.0.tar";
+    sha256 = "sha256-lm+sLSx1np3m6WnBCtp6ezBsET9/HgfqN2gp7IY4Dao=";
+  };
+
+  nativeBuildInputs = [ autoPatchelfHook ];
+  buildInputs = [
+    elfutils
+    zlib
+    rocmRuntime
+    stdenv.cc.cc.lib
+  ];
+  phases = [ "unpackPhase" "installPhase" "fixupPhase" ];
+  dontStrip = true;
+
+  installPhase = ''
+    mkdir -p $out
+    cp -a . $out/
+
+    ln -s ${lib.getLib libffi}/lib/libffi.so $out/lib/libffi.so.6
+  '';
+
+  passthru = {
+    inherit rocmRuntime;
+    isClang = true; # Needed for wrapCCWith
+  };
+
+  meta.mainProgram = "clang";
+}

pkgs/bench6/default.nix

@@ -27,10 +27,13 @@ stdenv.mkDerivation rec {
     rev = gitCommit;
   };
 
-  buildInputs = [
-    bigotes
+  nativeBuildInputs = [
     cmake
     clangOmpss2
+  ];
+
+  buildInputs = [
+    bigotes
     openmp
     openmpv
     nanos6

pkgs/bigotes/default.nix

@@ -4,7 +4,7 @@
 , cmake
 }:
 
-stdenv.mkDerivation rec {
+stdenv.mkDerivation {
   pname = "bigotes";
   version = "9dce13";
   src = fetchFromGitHub {
@@ -13,5 +13,5 @@ stdenv.mkDerivation rec {
     rev = "9dce13446a8da30bea552d569d260d54e0188518";
     sha256 = "sha256-ktxM3pXiL8YXSK+/IKWYadijhYXqGoLY6adLk36iigE=";
   };
-  buildInputs = [ cmake ];
+  nativeBuildInputs = [ cmake ];
 }

pkgs/clsparse/install_target.patch

@@ -0,0 +1,53 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 3d139ed..15ffc14 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -176,32 +179,22 @@ if( BUILD_clSPARSE OR BUILD_SAMPLES )
+   if( BUILD_clSPARSE )
+     message( STATUS "Setting up clSPARSE external..." )
+ 
+-    if ( BUILD_SAMPLES )
+-      # If the user elects to build samples, then we must build and install clSPARSE
+-      # The install location is set as a subdirectory of the SuperBuild
+-      ExternalProject_Add(
+-        clSPARSE
+-        DEPENDS ${clSPARSE.Dependencies}
+-        SOURCE_DIR ${PROJECT_SOURCE_DIR}/src
+-        BINARY_DIR clSPARSE-build
+-        INSTALL_DIR clSPARSE-package
+-        CMAKE_ARGS ${clSPARSE.Cmake.Args} -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
+-        -DBUILD_CLVERSION=${BUILD_CLVERSION} -DCMAKE_INSTALL_PREFIX=<INSTALL_DIR>
+-        -DUSE_SYSTEM_CL2HPP:BOOL=${USE_SYSTEM_CL2HPP}
+-      )
+-    else( )
+-      # If the user does not want to build samples, then build clSPARSE but don't automatically
+-      # install it
+-      ExternalProject_Add(
+-        clSPARSE
+-        DEPENDS ${clSPARSE.Dependencies}
+-        SOURCE_DIR ${PROJECT_SOURCE_DIR}/src
+-        BINARY_DIR clSPARSE-build
+-        CMAKE_ARGS ${clSPARSE.Cmake.Args} -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
+-        -DBUILD_CLVERSION=${BUILD_CLVERSION} -DUSE_SYSTEM_CL2HPP:BOOL=${USE_SYSTEM_CL2HPP}
+-        INSTALL_COMMAND ""
+-      )
+-    endif( )
++    ExternalProject_Add(
++      clSPARSE
++      DEPENDS ${clSPARSE.Dependencies}
++      SOURCE_DIR ${PROJECT_SOURCE_DIR}/src
++      BINARY_DIR clSPARSE-build
++      INSTALL_DIR clSPARSE-package
++      CMAKE_ARGS ${clSPARSE.Cmake.Args} -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
++      -DBUILD_CLVERSION=${BUILD_CLVERSION} -DCMAKE_INSTALL_PREFIX=<INSTALL_DIR>
++      -DUSE_SYSTEM_CL2HPP:BOOL=${USE_SYSTEM_CL2HPP}
++    )
++
++    install(
++      DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/clSPARSE-package/
++      DESTINATION ${CMAKE_INSTALL_PREFIX}
++      USE_SOURCE_PERMISSIONS
++    )
+ 
+   endif( )
+ 

pkgs/clsparse/package.nix

@@ -0,0 +1,70 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchpatch,
+  boost,
+  gtest,
+  ocl-icd,
+  opencl-headers,
+  opencl-clhpp,
+  cmake,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "clsparse";
+  version = "0.10.2.0";
+
+  src = fetchFromGitHub {
+    owner = "clMathLibraries";
+    repo = "clSPARSE";
+    rev = "v${version}";
+    hash = "sha256-jIauCtUyPEIx7pFI3qH0WagV+t/fvro0OsGgONBJm0s=";
+  };
+
+  patches = [
+    ./pass_include_dir.patch
+    ./install_target.patch
+    (fetchpatch {
+      name = "remove-gettypecode.patch";
+      url = "https://patch-diff.githubusercontent.com/raw/clMathLibraries/clSPARSE/pull/210.patch";
+      hash = "sha256-9Q+tk7RMdWE4MCnbvWlsI0MIgBYKIWR2jIC1bICtIjU=";
+    })
+  ];
+
+  postInstallPhase = ''
+    mv $installDir/lib64 lib
+    ln -s lib/ lib64
+  '';
+
+  env.NIX_CFLAGS_COMPILE = "-std=c++17";
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    boost
+    ocl-icd
+    opencl-headers
+    opencl-clhpp
+  ];
+
+  cmakeFlags = [
+    "-DBUILD_Boost=OFF"
+    "-DBUILD_gMock=OFF"
+    "-DBUILD_MTX=OFF"
+    "-DBUILD_SAMPLES=OFF"
+    "-DUSE_SYSTEM_CL2HPP=ON"
+    "-DGMOCK_ROOT=${gtest}"
+    "-DGTEST_INCLUDE_DIR=${gtest.src}/googletest/include"
+  ];
+
+  meta = {
+    description = "A software library containing Sparse functions written in OpenCL";
+    homepage = "https://github.com/clMathLibraries/clSPARSE";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ leixb ];
+    platforms = lib.platforms.all;
+  };
+}

pkgs/clsparse/pass_include_dir.patch

@@ -0,0 +1,14 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 3d139ed..b7ea2d3 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -132,6 +132,9 @@ else( )
+       set( GMOCK_ROOT "$ENV{GMOCK_ROOT}" )
+     endif( )
+     list( APPEND clSPARSE.Cmake.Args -DGTEST_ROOT=${GMOCK_ROOT} )
++    if( DEFINED GTEST_INCLUDE_DIR )
++      list( APPEND clSPARSE.Cmake.Args -DGTEST_INCLUDE_DIR=${GTEST_INCLUDE_DIR} )
++    endif( )
+   endif( )
+ endif( )
+ 

pkgs/extrae/default.nix

@@ -20,6 +20,7 @@
 #, python3Packages
 , installShellFiles
 , symlinkJoin
+, enablePapi ? stdenv.hostPlatform == stdenv.buildPlatform # Disabled when cross-compiling
 }:
 
 let
@@ -87,7 +88,7 @@ stdenv.mkDerivation rec {
       --enable-sampling
       --with-unwind=${libunwind.dev}
       --with-xml-prefix=${libxml2.dev}
-      --with-papi=${papi}
+      ${lib.optionalString enablePapi "--with-papi=${papi}"}
       ${if (mpi != null) then ''--with-mpi=${mpi}''
         else ''--without-mpi''}
       --without-dyninst)

pkgs/intel-oneapi/2023.nix

@@ -45,40 +45,31 @@ let
     installPhase = ''
       awk -F': ' '\
         BEGIN   { print "[ {" } \
-        NR>1 && /^Package: / { print "} {"; } \
+        NF==0 { empty=1; } \
+        NF && empty { print "} {"; empty=0; } \
         /: /    { printf "%s = \"%s\";\n", $1, $2 } \
         END     { print "} ]" }' $srcs > $out
     '';
   };
 
-  aptPackages = import aptPackageIndex;
-
-  apthost = "https://apt.repos.intel.com/oneapi/";
-
-  getSum = pkgList: name:
+  findMatch = name:
   let
-    matches = lib.filter (x: name == x.Package) pkgList;
-    #n = lib.length matches;
-    #match = builtins.trace (name + " -- ${builtins.toString n}") (lib.elemAt matches 0);
-    match = lib.elemAt matches 0;
-  in
-    match.SHA256;
-
-  getUrl = pkgList: name:
-  let
-    matches = lib.filter (x: name == x.Package) pkgList;
-    #match = assert lib.length matches == 1; lib.elemAt matches 0;
+    aptPackages = import aptPackageIndex;
+    matches = lib.filter (x: name == x.Package) aptPackages;
     n = lib.length matches;
-    match =
-      #builtins.trace (name + " -- n=${builtins.toString n}")
-      (lib.elemAt matches 0);
+    match = builtins.traceVerbose (name + " -- ${builtins.toString n}") (builtins.head matches);
+
+    apthost = "https://apt.repos.intel.com/oneapi/";
   in
-    apthost + match.Filename;
+    {
+      url = apthost + match.Filename;
+      sha256 = match.SHA256;
+    };
 
   uncompressDebs = debs: name: stdenv.mkDerivation {
     name = name;
     srcs = debs;
-    buildInputs = [ dpkg ];
+    nativeBuildInputs = [ dpkg ];
     phases = [ "installPhase" ];
     installPhase = ''
       mkdir -p $out
@@ -91,10 +82,7 @@ let
 
   joinDebs = name: names:
   let
-    urls = builtins.map (x: getUrl aptPackages x) names;
-    sums = builtins.map (x: getSum aptPackages x) names;
-    getsrc = url: sha256: builtins.fetchurl { inherit url sha256; };
-    debs = lib.zipListsWith getsrc urls sums;
+    debs = builtins.map (x: builtins.fetchurl (findMatch x)) names;
   in
     uncompressDebs debs "${name}-source";
 
@@ -108,14 +96,17 @@ let
       "intel-oneapi-mpi-${version}"
     ];
 
-    buildInputs = [
+    nativeBuildInputs = [
+      autoPatchelfHook
       rsync
+    ];
+
+    buildInputs = [
       libfabric
       zlib
       stdenv.cc.cc.lib
     ];
 
-    nativeBuildInputs = [ autoPatchelfHook ];
     phases = [ "installPhase" "fixupPhase" ];
     dontStrip = true;
     installPhase = ''
@@ -154,7 +145,6 @@ let
 
     buildInputs = [
       intel-mpi
-      rsync
       libffi_3_3
       libelf
       libxml2
@@ -162,7 +152,10 @@ let
       stdenv.cc.cc.lib
     ];
 
-    nativeBuildInputs = [ autoPatchelfHook ];
+    nativeBuildInputs = [
+      autoPatchelfHook
+      rsync
+    ];
     phases = [ "installPhase" "fixupPhase" ];
     dontStrip = true;
 
@@ -192,7 +185,6 @@ let
     buildInputs = [
       intel-mpi
       intel-tbb
-      rsync
       libffi_3_3
       libelf
       libxml2
@@ -201,7 +193,10 @@ let
       stdenv.cc.cc.lib
     ];
 
-    nativeBuildInputs = [ autoPatchelfHook ];
+    nativeBuildInputs = [
+      autoPatchelfHook
+      rsync
+    ];
     phases = [ "installPhase" "fixupPhase" ];
     dontStrip = true;
 
@@ -254,7 +249,6 @@ let
     buildInputs = [
       intel-mpi
       intel-compiler-shared
-      rsync
       libffi_3_3
       libelf
       libxml2
@@ -262,7 +256,10 @@ let
       stdenv.cc.cc.lib
     ];
 
-    nativeBuildInputs = [ autoPatchelfHook ];
+    nativeBuildInputs = [
+      autoPatchelfHook
+      rsync
+    ];
 
     phases = [ "installPhase" "fixupPhase" ];
 
@@ -337,7 +334,6 @@ let
 
     buildInputs = [
       intel-compiler-shared
-      rsync
       libffi_3_3
       libelf
       libxml2
@@ -345,7 +341,10 @@ let
       stdenv.cc.cc.lib
     ];
 
-    nativeBuildInputs = [ autoPatchelfHook ];
+    nativeBuildInputs = [
+      autoPatchelfHook
+      rsync
+    ];
     autoPatchelfIgnoreMissingDeps = [ "libtbb.so.12" "libtbbmalloc.so.2" "libze_loader.so.1" ];
 
     phases = [ "installPhase" "fixupPhase" ];
@@ -442,7 +441,7 @@ let
     '';
   };
 
-  ifort-wrapper = wrapIntel rec {
+  ifort-wrapper = wrapIntel {
     cc = intel-compiler-fortran;
     mygcc = gcc;
     extraBuild = ''

pkgs/intel-oneapi/packages.nix

@@ -0,0 +1,205 @@
+{ lib
+, stdenv
+, callPackage
+, dpkg
+, fetchurl
+, recurseIntoAttrs
+
+, sqlite
+, elfutils
+}:
+
+let
+  inherit (builtins)
+    elem attrNames attrValues concatMap filter fromJSON getAttr groupBy head isNull listToAttrs map mapAttrs readFile replaceStrings splitVersion ;
+  inherit (lib)
+    converge findFirst groupBy' hasPrefix optional pipe take toInt toList versionAtLeast versionOlder ;
+
+  aptData = fromJSON (readFile ./packages.json);
+
+  # Compare versions in debian control file syntax
+  # See: https://www.debian.org/doc/debian-policy/ch-relationships.html#syntax-of-relationship-fields
+  #
+  # NOTE: this is not a proper version comparison
+  #
+  # A proper version solver, should aggregate dependencies with the same name
+  # and compute the constraint (e.g. a (>= 2) a (<< 5) -> 2 <= a << 5)
+  #
+  # But in the intel repo, there are no such "duplicated" dependencies to specify
+  # upper limits, which leads to issues when intel-hpckit-2021 depends on things
+  # like intel-basekit >= 2021.1.0-2403 and we end up installing the newest
+  # basekit instead of the one from 2021.
+  #
+  # To mitigate this, >= is set to take the latest version with matching major
+  # and minor (only revision and patch are allowed to change)
+  compareVersions = got: kind: want:
+    let
+      g0 = take 2 (splitVersion got);
+      w0 = take 2 (splitVersion want);
+    in if isNull want then true
+    else if kind == "=" then got == want
+    else if kind == "<<" then versionOlder got want
+    else if kind == "<=" then versionAtLeast want got
+    else if kind == ">>" then versionOlder want got
+    else if kind == ">=" then (g0 == w0) && versionAtLeast got want # always match major version
+    else throw "unknown operation: ${kind}";
+
+  findMatching = { pname, kind, version }:
+    findFirst (x: pname == x.pname && compareVersions x.version kind version) null aptData;
+
+  isIntel = pkg: (hasPrefix "intel-" pkg.pname);
+
+  expandDeps = pkg: (map findMatching (filter isIntel pkg.dependencies)) ++ (optional (pkg.size != 0) pkg);
+
+  # get the oldest by major version. If they have the same major version, take
+  # the newest. This prevents most issues with resolutions
+  # versionOlder b a -> true if b is older than a (b `older` a)
+  getNewerInMajor = a: b: let
+    va = a.version;
+    vb = b.version;
+    va0 = head (splitVersion va);
+    vb0 = head (splitVersion vb);
+  in
+  if isNull a then b
+  else if va0 != vb0 then
+    if va0 > vb0 then b else a
+  else if versionOlder vb va then a else b;
+  removeDups = l: attrValues (groupBy' getNewerInMajor null (getAttr "provides") l);
+
+  _resolveDeps = converge (l: removeDups (concatMap expandDeps l));
+  resolveDeps = pkg: let deps = _resolveDeps (toList pkg);
+      namedDeps = (map (x: "${x.pname}-${x.version}") deps);
+    in builtins.traceVerbose (builtins.deepSeq namedDeps namedDeps) deps;
+
+  blacklist = [
+    "intel-basekit-env"
+    "intel-basekit-getting-started"
+    "intel-hpckit-env"
+    "intel-hpckit-getting-started"
+    "intel-oneapi-advisor"
+    "intel-oneapi-common-licensing"
+    "intel-oneapi-common-oneapi-vars"
+    "intel-oneapi-common-vars"
+    "intel-oneapi-compiler-cpp-eclipse-cfg"
+    "intel-oneapi-compiler-dpcpp-eclipse-cfg"
+    "intel-oneapi-condaindex"
+    "intel-oneapi-dev-utilities-eclipse-cfg"
+    "intel-oneapi-dpcpp-ct-eclipse-cfg"
+    "intel-oneapi-eclipse-ide"
+    "intel-oneapi-hpc-toolkit-getting-started"
+    "intel-oneapi-icc-eclipse-plugin-cpp"
+    "intel-oneapi-vtune"
+    "intel-oneapi-vtune-eclipse-plugin-vtune"
+  ];
+
+  isInBlacklist = pkg: elem pkg.provides blacklist;
+  removeBlacklist = filter (e: !(isInBlacklist e));
+
+  dpkgExtractAll = pname: version: {srcs, deps}: stdenv.mkDerivation {
+    inherit pname version srcs;
+
+    nativeBuildInputs = [ dpkg ];
+    phases = [ "installPhase" ];
+
+    passthru = { inherit deps; };
+
+    installPhase = ''
+      mkdir -p $out
+      for src in $srcs; do
+        echo "Unpacking $src"
+        dpkg -x $src $out
+      done
+    '';
+  };
+
+  apthost = "https://apt.repos.intel.com/oneapi/";
+  fetchDeb = p: fetchurl { url = apthost + p.filename; inherit (p) sha256; };
+
+  buildIntel = pkg: pipe pkg [
+    resolveDeps
+    removeBlacklist
+    (l: {srcs = map fetchDeb l; deps = l; })
+    (dpkgExtractAll "${pkg.provides}-extracted" pkg.version)
+  ];
+
+  findHpcKit = year: findMatching { pname = "intel-hpckit"; kind = "<<"; version = toString (year+1); };
+  years = map toInt (attrNames components);
+
+  patchIntel = callPackage ./patch_intel.nix { };
+
+  # Version information for each hpckit. This is used to normalize the paths
+  # so that files are in $out/{bin,lib,include...} instead of all over the place
+  # in $out/opt/intel/oneapi/*/*/{...}.
+  #
+  # The most important is the compiler component, which is used to build the
+  # stdenv for the hpckit.
+  #
+  # NOTE: this have to be manually specified, so we can avoid IFD. To add a
+  # new version, add a new field with an empty attrset, (e.g. "2026" = {}; ),
+  # build hpckit_2026.unpatched and use the values from
+  # result/opt/intel/oneapi/* to populate the attrset.
+  #
+  # WARN: if there are more than one version in the folders of the unpatched
+  # components, our dependency resolution hacks have probably failed and the
+  # package set may be broken.
+  components = {
+    "2025" = {
+      ishmem = "1.3";
+      pti = "0.12";
+      tcm = "1.3";
+      umf = "0.10";
+
+      ccl = "2021.15";
+      compiler = "2025.1";
+      dal = "2025.5";
+      debugger = "2025.1";
+      dev-utilities = "2025.1";
+      dnnl = "2025.1";
+      dpcpp-ct = "2025.1";
+      dpl = "2022.8";
+      ipp = "2022.1";
+      ippcp = "2025.1";
+      mkl = "2025.1";
+      mpi = "2021.15";
+      tbb = "2022.1";
+    };
+    "2024" = {
+      tcm = "1.1";
+
+      ccl = "2021.13";
+      compiler = "2024.2";
+      dal = "2024.6";
+      debugger = "2024.2";
+      dev-utilities = "2024.2";
+      diagnostics = "2024.2";
+      dnnl = "2024.2";
+      dpcpp-ct = "2024.2";
+      dpl = "2022.6";
+      ipp = "2021.12";
+      ippcp = "2021.12";
+      mkl = "2024.2";
+      mpi = "2021.13";
+      tbb = "2021.13";
+
+      extraPackages = [
+        sqlite
+        elfutils
+      ];
+    };
+  };
+
+  replaceDots = replaceStrings ["."] ["_"];
+
+in recurseIntoAttrs (listToAttrs (map (year: let
+      year_str = toString year;
+    in {
+      name = "hpckit_${year_str}";
+      value = patchIntel {unpatched = buildIntel (findHpcKit year); components = components.${year_str}; };
+  }) years)) // {
+  apt = pipe aptData [
+    (groupBy (p: replaceDots p.provides))
+    (mapAttrs (_: l: listToAttrs (map (pkg: { name = replaceDots ("v" + pkg.version); value = pkg; }) l)))
+  ] ;
+
+  inherit resolveDeps patchIntel buildIntel;
+}

pkgs/intel-oneapi/patch_intel.nix

@@ -0,0 +1,177 @@
+{ stdenv
+, stdenvNoCC
+, lib
+, symlinkJoin
+, autoPatchelfHook
+, wrapCCWith
+, overrideCC
+, gcc13
+, hwloc
+, libelf
+, libffi_3_3
+, libpsm2
+, libuuid
+, libxml2
+, numactl
+, ocl-icd
+, openssl
+, python3
+, rdma-core
+, ucx
+, zlib
+, makeOverridable
+, recurseIntoAttrs
+}:
+
+makeOverridable (
+{
+  unpatched,
+  components ? { },
+  extraPackages ? components.extraPackages or []
+}:
+
+let
+  inherit (builtins) attrValues filter mapAttrs removeAttrs;
+
+  gcc = gcc13;
+
+  __components = removeAttrs components ["extraPackages"];
+  _components = __components;
+  # _components = lib.traceSeqN 2 {
+  #   inherit unpatched __components;
+  #   deps = builtins.map (x: "${x.pname}-${x.version}") unpatched.deps;
+  # } __components;
+
+  wrapIntel = { cc, extraBuildCommands ? "", extraInstall ? "", ... }@args:
+    let
+      targetConfig = stdenv.targetPlatform.config;
+    in (wrapCCWith {
+      inherit cc;
+      extraBuildCommands = ''
+        echo "-L${gcc.cc}/lib/gcc/${targetConfig}/${gcc.version}" >> $out/nix-support/cc-ldflags
+        echo "-L${gcc.cc.lib}/lib" >> $out/nix-support/cc-ldflags
+        echo "-L${cc}/lib" >> $out/nix-support/cc-ldflags
+
+        # echo "--gcc-toolchain=${gcc.cc}" >> $out/nix-support/libcxx-cxxflags
+        echo "--gcc-toolchain=${gcc.cc}" >> $out/nix-support/cc-cflags
+
+        # For some reason, If we don't resolve the realpath things go wrong
+        for stddef in ${cc}/lib/clang/*/include/stddef.h ; do
+          dir=$(dirname $(realpath "$stddef"))
+          echo "-isystem $dir" >> $out/nix-support/cc-cflags
+        done
+
+        echo "-isystem ${cc}/include" >> $out/nix-support/cc-cflags
+        echo "-isystem ${cc}/include/intel64" >> $out/nix-support/cc-cflags
+
+        for dir in ${gcc.cc}/lib/gcc/${targetConfig}/*/include; do
+          echo "-isystem $dir" >> $out/nix-support/cc-cflags
+        done
+
+        for dir in ${gcc.cc}/include/c++/*; do
+          echo "-isystem $dir" >> $out/nix-support/libcxx-cxxflags
+        done
+        for dir in ${gcc.cc}/include/c++/*/${targetConfig}; do
+          echo "-isystem $dir" >> $out/nix-support/libcxx-cxxflags
+        done
+
+        # FIXME: We should find a better way to modify the PATH instead of using
+        # this ugly hack. See https://jungle.bsc.es/git/rarias/bscpkgs/issues/9
+        echo 'path_backup="${gcc.cc}/bin:$path_backup"' >> $out/nix-support/cc-wrapper-hook
+
+        # Disable hardening by default
+        echo "" > $out/nix-support/add-hardening.sh
+      '' + extraBuildCommands;
+    } // (removeAttrs args ["cc" "extraBuildCommands" "extraInstall"])
+    ).overrideAttrs (old: {
+      installPhase = old.installPhase + extraInstall;
+    });
+
+in
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = lib.removeSuffix "-extracted" unpatched.pname;
+  inherit (unpatched) version;
+  src = unpatched;
+
+  phases = [ "installPhase" "fixupPhase" ];
+  buildInputs = [
+    libffi_3_3
+    libelf
+    libxml2
+    hwloc
+    numactl
+    libuuid
+    libpsm2
+    zlib
+    ocl-icd
+    rdma-core
+    ucx
+    openssl
+    python3
+    stdenv.cc.cc.lib
+  ] ++ extraPackages;
+
+  autoPatchelfIgnoreMissingDeps = [ "libhwloc.so.5" "libcuda.so.1" "libze_loader.so.1" ];
+
+  dontCheckForBrokenSymlinks = true;
+
+  nativeBuildInputs = [ autoPatchelfHook ];
+  installPhase = ''
+    cp -r $src/opt/intel/oneapi/ $out
+  '';
+
+  passthru = let
+    pkgs = mapAttrs
+      (folder: version: symlinkJoin {
+        pname = "intel-${folder}";
+        inherit version;
+        paths = ["${finalAttrs.finalPackage}/${folder}/${version}"];
+      })
+      _components;
+  in pkgs // {
+    inherit unpatched;
+    pkgs = recurseIntoAttrs pkgs;
+    components = _components;
+
+    # This contains all packages properly symlinked into toplevel directories
+    # in $out.
+    #
+    # NOTE: there are clashes with packages that have symlinks outside their
+    # scope (libtcm and env/vars.sh)
+    all = symlinkJoin {
+      pname = finalAttrs.finalPackage + "-symlinked";
+      inherit (finalAttrs.finalPackage) version;
+      paths = filter lib.isDerivation (attrValues finalAttrs.finalPackage.pkgs);
+    };
+
+    stdenv = overrideCC stdenv finalAttrs.finalPackage.cc;
+
+    cc = wrapIntel {
+      cc = finalAttrs.finalPackage.pkgs.compiler;
+      extraBuildCommands = ''
+        wrap icx  $wrapper $ccPath/icx
+        wrap icpx $wrapper $ccPath/icpx
+        wrap ifx  $wrapper $ccPath/ifx
+
+        ln -s $out/bin/icpx $out/bin/c++
+        ln -s $out/bin/icx  $out/bin/cc
+
+        # Use this to detect when a compiler subprocess is called
+        # from icpx (--fsycl-host-compiler)
+        echo 'export "NIX_CC_WRAPPER_INTEL=1"' >> $out/nix-support/cc-wrapper-hook
+
+        sed -i 's/.*isCxx=0/isCxx=1/' $out/bin/icpx
+
+        # oneMath looks for sycl libraries in bin/../lib
+        ln -s ${finalAttrs.finalPackage.pkgs.compiler}/lib $out/lib
+        ln -s ${finalAttrs.finalPackage.pkgs.compiler}/include $out/include
+      '';
+      extraInstall = ''
+        export named_cc="icx"
+        export named_cxx="icpx"
+        export named_fc="ifx"
+      '';
+    };
+  };
+
+}))

pkgs/intel-oneapi/process.jq

@@ -0,0 +1,29 @@
+#!/usr/bin/env -S jq -f
+
+def extract_fields: {
+        pname : .Package,
+        version : .Version,
+        provides : .Package | sub("[0-9.-]*$"; ""),
+        filename : .Filename,
+        size : ."Installed-Size" | tonumber,
+        sha256 : .SHA256,
+        dependencies : .Depends,
+    } ;
+
+# parses dependencies into a list of [{.pname, .kind, .version}]
+# some dependencies do not have a version specified, in which case, version = version = null
+#
+# example dependencies:
+# intel-oneapi-common-vars (>= 2023.0.0-25325), intel-oneapi-common-licensing-2023.0.0
+
+def split_dependencies : map(try(.dependencies |= split(",\\s?"; "")) // .dependencies |= []) ;
+
+def match_version : capture("(?<pname>[a-zA-Z0-9_\\-.]*) *(\\((?<kind>[<>=]*) *(?<version>.*)\\))?"; "") ;
+
+def parse_dependencies : map_values(.dependencies.[] |= match_version) ;
+
+def sort_version_decreasing : sort_by(.version | split("[-.]"; "") | map(tonumber)) | reverse ;
+
+map(extract_fields) | split_dependencies | parse_dependencies | sort_version_decreasing
+
+# [.[] | select(.pname == "intel-hpckit") | .version]

pkgs/intel-oneapi/toJson.awk

@@ -0,0 +1,29 @@
+#!/usr/bin/env -S awk -f
+
+BEGIN   {
+    FS=": "
+
+    prev_empty=1
+    t="  "
+
+    print "[ {"
+}
+
+!NF { # empty line, update separator so next non empty line closes the dict
+    prev_empty=1
+    t="},\n{ "
+    next # skip line (we won't match anything else)
+}
+
+{
+    printf t "\"%s\" : \"%s\"\n", $1, $2
+
+    if (prev_empty) {
+        # we were the first after a group of empty lines, following ones have to
+        # have a comma
+        prev_empty=0
+        t=", "
+    }
+}
+
+END     { print "} ]" }

pkgs/intel-oneapi/update.sh

@@ -2,3 +2,5 @@
 
 curl https://apt.repos.intel.com/oneapi/dists/all/main/binary-amd64/Packages -o amd64-packages
 curl https://apt.repos.intel.com/oneapi/dists/all/main/binary-all/Packages -o all-packages
+
+cat amd64-packages all-packages | ./toJson.awk | ./process.jq >packages.json

pkgs/llvm-ompss2/clang.nix

@@ -43,32 +43,36 @@ let
 
   source = if (useGit) then git else release;
 
-in stdenv.mkDerivation rec {
+in stdenv.mkDerivation {
   pname = "clang-ompss2";
   inherit (source) src version;
 
   enableParallelBuilding = true;
-  isClang = true;
 
   passthru = {
     CC = "clang";
     CXX = "clang++";
+
+    isClang = true;
+    isClangWithOmpss = true;
+
+    inherit gcc zlib;
   };
 
-  isClangWithOmpss = true;
-
-  nativeBuildInputs = [ zlib ];
-
-  buildInputs = [
-    which
+  nativeBuildInputs = [
     bash
+    cmake
+    elfutils
+    llvmPackages_latest.lld
+    pkg-config
     python3
     perl
-    cmake
-    llvmPackages_latest.lld
-    elfutils
+    which
+    zlib
+  ];
+
+  buildInputs = [
     libffi
-    pkg-config
     zlib
     gcc.cc.lib # Required for libstdc++.so.6
   ];

pkgs/llvm-ompss2/default.nix

@@ -2,16 +2,18 @@
   stdenv
 , lib
 , gcc
+, gcc13
 , clangOmpss2Unwrapped
+, writeShellScript
 , openmp ? null
 , wrapCCWith
 , llvmPackages_latest
 , ompss2rt ? null
 }:
 
-with lib;
-
 let
+  inherit (lib) assertMsg optional optionalString;
+
   usingNodesAndOmpv = (openmp.pname == "openmp-v" && ompss2rt.pname == "nodes");
   sameNosv = openmp.nosv == ompss2rt.nosv;
 in
@@ -36,11 +38,9 @@ let
   targetConfig = stdenv.targetPlatform.config;
   inherit gcc;
   cc = clangOmpss2Unwrapped;
-  gccVersion = with versions; let v = gcc.version; in concatStringsSep "." [(major v) (minor v) (patch v)];
-in wrapCCWith {
-  inherit cc bintools;
-  # extraPackages adds packages to depsTargetTargetPropagated
-  extraPackages = optional (openmp != null) openmp;
+
+  gccVersion = with lib.versions; let v = gcc.version; in concatStringsSep "." [(major v) (minor v) (patch v)];
+
   extraBuildCommands = ''
     echo "-target ${targetConfig}" >> $out/nix-support/cc-cflags
     echo "-B${gcc.cc}/lib/gcc/${targetConfig}/${gccVersion}" >> $out/nix-support/cc-cflags
@@ -57,14 +57,51 @@ in wrapCCWith {
     echo "--gcc-toolchain=${gcc}" >> $out/nix-support/cc-cflags
 
     wrap clang++  $wrapper $ccPath/clang++
-
-  '' + optionalString (openmp != null) ''
-    echo "export OPENMP_RUNTIME=${ompname}" >> $out/nix-support/cc-wrapper-hook
-  '' + optionalString (ompss2rt != null) ''
-    echo "export OMPSS2_RUNTIME=${rtname}" >> $out/nix-support/cc-wrapper-hook
-    echo "export ${homevar}=${ompss2rt}"   >> $out/nix-support/cc-wrapper-hook
-  '' + optionalString (ompss2rt != null && ompss2rt.pname == "nodes") ''
-    echo "export NOSV_HOME=${ompss2rt.nosv}" >> $out/nix-support/cc-wrapper-hook
   '';
-}
 
+  envExports = lib.optionalString (openmp != null) ''
+      echo "export OPENMP_RUNTIME=${ompname}" >> $out/nix-support/cc-wrapper-hook
+    '' + optionalString (ompss2rt != null) ''
+      echo "export OMPSS2_RUNTIME=${rtname}" >> $out/nix-support/cc-wrapper-hook
+      echo "export ${homevar}=${ompss2rt}"   >> $out/nix-support/cc-wrapper-hook
+    '' + optionalString (ompss2rt != null && ompss2rt.pname == "nodes") ''
+      echo "export NOSV_HOME=${ompss2rt.nosv}" >> $out/nix-support/cc-wrapper-hook
+    '';
+
+  extraPackages = optional (openmp != null) openmp;
+
+  wrappedCC = wrapCCWith {
+    # extraPackages adds packages to depsTargetTargetPropagated
+    inherit cc bintools extraPackages;
+    extraBuildCommands = extraBuildCommands + envExports;
+  };
+
+  resetIntelCCFlags = let tconf = builtins.replaceStrings ["-"] ["_"] targetConfig;
+  in writeShellScript "remove-intel.sh" ''
+    if [ "''${NIX_CC_WRAPPER_INTEL:-0}" = 1 ]; then
+      unset NIX_CFLAGS_COMPILE_${tconf}
+      unset NIX_CC_WRAPPER_FLAGS_SET_${tconf}
+
+      if (( "''${NIX_DEBUG:-0}" >= 1 )); then
+        echo "ompss2: cleaned NIX_CFLAGS_COMPILE_${tconf} (invokation from intel compiler detected)"
+      fi
+    fi
+  '';
+
+  intelExtraBuildCommands = ''
+    sed -i 's|# Flirting.*|source ${resetIntelCCFlags}\n\n&|' $out/bin/clang
+    sed -i 's|# Flirting.*|source ${resetIntelCCFlags}\n\n&|' $out/bin/clang++
+  '';
+
+  wrappedCCIntel = wrapCCWith {
+    inherit bintools extraPackages;
+    cc = cc.override { gcc = gcc13; }; # Intel uses gcc13, so we have to match it
+    # extraPackages adds packages to depsTargetTargetPropagated
+    extraBuildCommands = intelExtraBuildCommands + envExports;
+  };
+
+in wrappedCC.overrideAttrs (oldAttrs: {
+    passthru = oldAttrs.passthru // {
+      forIcpx = wrappedCCIntel;
+    };
+  })

pkgs/lmbench/default.nix

@@ -22,7 +22,11 @@ stdenv.mkDerivation rec {
   '';
 
   buildInputs = [ libtirpc ];
-  patches = [ ./fix-install.patch ./gcc-14.patch ];
+  patches = [
+    ./fix-install.patch
+    ./gcc-14.patch
+    ./fix-cross.patch
+  ];
 
   hardeningDisable = [ "all" ];
 
@@ -35,6 +39,8 @@ stdenv.mkDerivation rec {
       CFLAGS=-Wno-implicit-int
       CPPFLAGS=-I${libtirpc.dev}/include/tirpc
       LDFLAGS=-ltirpc
+      CC=${stdenv.cc.targetPrefix}cc
+      AR=${stdenv.cc.targetPrefix}ar
     )
   '';
 

pkgs/lmbench/fix-cross.patch

@@ -0,0 +1,13 @@
+diff --git a/src/Makefile b/src/Makefile
+index 2555014..356eeb3 100644
+--- a/src/Makefile
++++ b/src/Makefile
+@@ -36,7 +36,7 @@ SHELL=/bin/sh
+ 
+ CC=`../scripts/compiler`
+ MAKE=`../scripts/make`
+-AR=ar
++AR?=ar
+ ARCREATE=cr
+ 
+ # base of installation location

pkgs/mcxx/default.nix

@@ -32,19 +32,22 @@ stdenv.mkDerivation rec {
 
   enableParallelBuilding = true;
 
-  buildInputs = [
+  nativeBuildInputs = [
     autoreconfHook
-    nanos6
-    gperf
+    bison
+    flex
     python3
     gfortran
     pkg-config
-    sqlite.dev
-    bison
-    flex
+    gperf
     gcc
   ];
 
+  buildInputs = [
+    nanos6
+    sqlite.dev
+  ];
+
   patches = [ ./intel.patch ];
 
   preConfigure = ''

pkgs/nanos6/default.nix

@@ -16,6 +16,7 @@
 , jemallocNanos6 ? null
 , cachelineBytes ? 64
 , enableGlibcxxDebug ? false
+, enablePapi ? stdenv.hostPlatform == stdenv.buildPlatform # Disabled when cross-compiling
 , useGit ? false
 , gitUrl ? "ssh://git@bscpm04.bsc.es/nanos6/nanos6"
 , gitBranch ? "master"
@@ -47,6 +48,8 @@ let
   };
 
   source = if (useGit) then git else release;
+
+  isCross = stdenv.hostPlatform != stdenv.buildPlatform;
 in
   stdenv.mkDerivation (source // {
     pname = "nanos6";
@@ -71,9 +74,11 @@ in
       "--disable-all-instrumentations"
       "--enable-ovni-instrumentation"
       "--with-ovni=${ovni}"
+      "--with-boost=${boost.dev}"
     ] ++
       (optional enableJemalloc "--with-jemalloc=${jemallocNanos6}") ++
-      (optional enableGlibcxxDebug "CXXFLAGS=-D_GLIBCXX_DEBUG");
+      (optional enableGlibcxxDebug "CXXFLAGS=-D_GLIBCXX_DEBUG") ++
+      (optional isCross "--with-symbol-resolution=ifunc");
 
     postConfigure = lib.optionalString (!enableDebug) ''
       # Disable debug
@@ -88,23 +93,29 @@ in
     dontStrip = enableDebug;
     separateDebugInfo = true;
 
-    buildInputs = [
+    nativeBuildInputs = [
       autoconf
       automake
       libtool
       pkg-config
+
+      # TODO: papi_version is needed for configure:
+      # ./configure: line 27378: papi_version: command not found
+      # This probably breaks cross-compilation
+    ] ++ lib.optionals enablePapi [ papi ];
+
+    buildInputs = [
       boost
       numactl
       hwloc
-      papi
       ovni
-    ];
+    ] ++ lib.optionals enablePapi [ papi ];
 
     # Create a script that sets NANOS6_HOME
     postInstall = ''
       mkdir -p $out/nix-support
       echo "export NANOS6_HOME=$out" >> $out/nix-support/setup-hook
-    ''; 
+    '';
 
     meta = with lib; {
       homepage = "https://github.com/bsc-pm/nanos6";

pkgs/nosv/default.nix

@@ -7,7 +7,7 @@
 , numactl
 , hwloc
 , papi
-, enablePapi ? true
+, enablePapi ? stdenv.hostPlatform == stdenv.buildPlatform # Disabled when cross-compiling
 , cacheline ? 64 # bits
 , ovni ? null
 , useGit ? false

pkgs/onemath/default.nix

@@ -0,0 +1,84 @@
+{ lib
+, fetchFromGitHub
+, cmake
+, withCFlags
+, intelPackages
+
+, mklSupport ? true
+
+, config
+
+, cudaSupport ? config.cudaSupport
+, cudaPackages ? { }
+
+, rocmSupport ? config.rocmSupport
+, hipTargets ? null # only one target at a time supported
+, rocmPackages ? { }
+}:
+
+let
+  # rocmSupport is not enough, we need a specific target
+  enableHip = rocmSupport && hipTargets != null;
+
+  stdenv = withCFlags (lib.optionals cudaSupport [ "--cuda-path=${cudaPackages.cudatoolkit}" ]) intelPackages.stdenv;
+in
+
+  # at least one backend has to be enabled
+  assert mklSupport || cudaSupport || enableHip;
+
+stdenv.mkDerivation rec {
+  pname = "oneMath";
+  version = "0.8";
+
+  src = fetchFromGitHub {
+    owner = "uxlfoundation";
+    repo = "oneMath";
+    rev = "v${version}";
+    sha256 = "sha256-xK8lKI3oqKlx3xtvdScpMq+HXAuoYCP0BZdkEqnJP5o=";
+  };
+
+  cmakeFlags = [
+    (lib.cmakeBool "ENABLE_MKLCPU_BACKEND"    mklSupport)
+    (lib.cmakeBool "ENABLE_MKLGPU_BACKEND"    mklSupport)
+
+    (lib.cmakeBool "ENABLE_CUBLAS_BACKEND"    cudaSupport)
+    (lib.cmakeBool "ENABLE_CUFFT_BACKEND"     cudaSupport)
+    (lib.cmakeBool "ENABLE_CURAND_BACKEND"    cudaSupport)
+    (lib.cmakeBool "ENABLE_CUSOLVER_BACKEND"  cudaSupport)
+    (lib.cmakeBool "ENABLE_CUSPARSE_BACKEND"  cudaSupport)
+
+    (lib.cmakeBool "ENABLE_ROCBLAS_BACKEND"   enableHip)
+    (lib.cmakeBool "ENABLE_ROCFFT_BACKEND"    enableHip)
+    (lib.cmakeBool "ENABLE_ROCSOLVER_BACKEND" enableHip)
+    (lib.cmakeBool "ENABLE_ROCRAND_BACKEND"   enableHip)
+    (lib.cmakeBool "ENABLE_ROCSPARSE_BACKEND" enableHip)
+
+    (lib.cmakeBool "BUILD_FUNCTIONAL_TESTS" false)
+    (lib.cmakeBool "BUILD_EXAMPLES" false)
+  ] ++ lib.optionals enableHip [
+    (lib.cmakeFeature "HIP_TARGETS" hipTargets)
+  ];
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = lib.optionals (mklSupport) [
+    intelPackages.mkl
+    intelPackages.tbb
+  ] ++ lib.optionals (enableHip) [
+    rocmPackages.rocmPath
+    rocmPackages.rocblas
+    rocmPackages.rocfft
+    rocmPackages.rocsolver
+    rocmPackages.rocrand
+    rocmPackages.rocsparse
+  ] ++ lib.optionals (cudaSupport) [
+    (lib.getDev cudaPackages.cuda_cudart)
+    cudaPackages.cudatoolkit
+
+    cudaPackages.libcublas
+    cudaPackages.libcurand
+    cudaPackages.libcufft
+    cudaPackages.libcusparse
+    cudaPackages.libcusolver
+  ];
+
+}

pkgs/osu/default.nix

@@ -24,9 +24,10 @@ stdenv.mkDerivation rec {
 
   doCheck = true;
   enableParallelBuilding = true;
+  nativeBuildInputs = [ mpiAll ];
   buildInputs = [ mpiAll ];
   hardeningDisable = [ "all" ];
-  configureFlags = [ 
+  configureFlags = [
       "CC=mpicc"
       "CXX=mpicxx"
   ];
@@ -40,7 +41,7 @@ stdenv.mkDerivation rec {
 
   meta = {
     description = "OSU Micro-Benchmarks";
-    homepage = http://mvapich.cse.ohio-state.edu/benchmarks/;
+    homepage = "http://mvapich.cse.ohio-state.edu/benchmarks/";
     maintainers = [ ];
     platforms = lib.platforms.all;
   };

pkgs/ovni/default.nix

@@ -13,8 +13,6 @@
 , useMpi ? (stdenv.buildPlatform.canExecute stdenv.hostPlatform)
 }:
 
-with lib;
-
 let
   release = rec {
     version = "1.12.0";
@@ -45,7 +43,7 @@ in
     postPatch = ''
       patchShebangs --build test/
     '';
-    nativeBuildInputs = [ cmake ];
+    nativeBuildInputs = [ cmake ] ++ lib.optionals (useMpi) [ mpi ];
     buildInputs = lib.optionals (useMpi) [ mpi ];
     cmakeBuildType = if (enableDebug) then "Debug" else "Release";
     cmakeFlags = [

pkgs/paraver/default.nix

@@ -1,5 +1,4 @@
-{
-  stdenv
+{ stdenv
 , fetchFromGitHub
 , autoreconfHook
 , boost
@@ -12,14 +11,17 @@
 , openssl
 , glibcLocales
 , wrapGAppsHook
+
+, enableDebug ? false
 }:
 
 let
   wx = wxGTK32;
-in
-stdenv.mkDerivation rec {
-  pname = "wxparaver";
   version = "4.12.0";
+in
+stdenv.mkDerivation {
+  pname = "wxparaver";
+  inherit version;
 
   src = fetchFromGitHub {
     owner = "bsc-performance-tools";
@@ -36,21 +38,26 @@ stdenv.mkDerivation rec {
     ./fix-boost-87.patch
   ];
 
-  hardeningDisable = [ "all" ];
-
   # Fix the PARAVER_HOME variable
   postPatch = ''
     sed -i 's@^PARAVER_HOME=.*$@PARAVER_HOME='$out'@g' docs/wxparaver
     sed -i '1aexport LOCALE_ARCHIVE="${glibcLocales}/lib/locale/locale-archive"' docs/wxparaver
   '';
 
-  dontStrip = true;
   enableParallelBuilding = true;
 
-  preConfigure = ''
-    export CFLAGS="-O3"
-    export CXXFLAGS="-O3"
-  '';
+  hardeningDisable = [ "all" ];
+
+  dontStrip = true;
+
+  env =
+    let
+      flags = if enableDebug then "-ggdb -Og" else "-O3";
+    in
+    {
+      CFLAGS = flags;
+      CXXFLAGS = flags;
+    };
 
   configureFlags = [
     "--with-boost=${boost}"
@@ -60,19 +67,19 @@ stdenv.mkDerivation rec {
   ];
 
   nativeBuildInputs = [
+    autoconf
+    automake
+    autoreconfHook
     wrapGAppsHook
   ];
 
   buildInputs = [
-    autoreconfHook
     boost
-    libxml2.dev
+    libxml2
     xml2
     wx
-    autoconf
-    automake
     paraverKernel
-    openssl.dev
+    openssl
   ];
 
   postInstall = ''

pkgs/paraver/kernel.nix

@@ -1,5 +1,4 @@
-{
-  stdenv
+{ stdenv
 , fetchFromGitHub
 , autoreconfHook
 , boost
@@ -9,11 +8,16 @@
 , automake
 , pkg-config
 , zlib
+
+, enableDebug ? false
 }:
 
-stdenv.mkDerivation rec {
-  pname = "paraver-kernel";
+let
   version = "4.12.0";
+in
+stdenv.mkDerivation {
+  pname = "paraver-kernel";
+  inherit version;
 
   src = fetchFromGitHub {
     owner = "bsc-performance-tools";
@@ -34,24 +38,31 @@ stdenv.mkDerivation rec {
 
   dontStrip = true;
 
-  preConfigure = ''
-    export CFLAGS="-O3 -DPARALLEL_ENABLED"
-    export CXXFLAGS="-O3 -DPARALLEL_ENABLED"
-  '';
+  env =
+    let
+      flags = "-DPARALLEL_ENABLED " + (if enableDebug then "-ggdb -Og" else "-O3");
+    in
+    {
+      CFLAGS = flags;
+      CXXFLAGS = flags;
+    };
 
   configureFlags = [
     "--with-boost=${boost}"
     "--enable-openmp"
   ];
 
-  buildInputs = [
+  nativeBuildInputs = [
     autoreconfHook
-    boost
-    libxml2.dev
-    xml2
     autoconf
     automake
     pkg-config
+  ];
+
+  buildInputs = [
+    boost
+    libxml2.dev
+    xml2
     zlib
   ];
 }

pkgs/paraver/release.nix

@@ -61,13 +61,16 @@ stdenv.mkDerivation rec {
     "--with-wx-config=${wx}/bin/wx-config"
   ];
 
+  nativeBuildInputs = [
+    autoconf
+    automake
+  ];
+
   buildInputs = [
     boost
     xml2
     libxml2.dev
     wx
-    autoconf
-    automake
     openssl.dev
   ];
 

pkgs/sonar/default.nix

@@ -18,8 +18,12 @@ stdenv.mkDerivation rec {
   hardeningDisable = [ "all" ];
   dontStrip = true;
   configureFlags = [ "--with-ovni=${ovni}" ];
-  buildInputs = [
+
+  nativeBuildInputs = [
     autoreconfHook
+  ];
+
+  buildInputs = [
     ovni
     mpi
   ];

pkgs/tacuda/default.nix

@@ -0,0 +1,68 @@
+{ stdenv
+, fetchFromGitHub
+, automake
+, autoconf
+, libtool
+, gnumake
+, autoreconfHook
+, boost
+, cudaPackages
+
+, useGit ? false
+, gitUrl ? "git@gitlab-internal.bsc.es:task-awareness/tacuda/tacuda.git"
+, gitBranch ? "main"
+, gitCommit ? "35234f9445e6149a2bd38d119841e2485d6ee05e"
+}:
+
+let
+
+  release_ver = "2.1.0";
+  release = {
+    version = release_ver;
+    src = fetchFromGitHub {
+      owner = "bsc-pm";
+      repo = "tacuda";
+      rev = release_ver;
+      hash = "sha256-Cj3EiLVJSLvRv0ydeg7Vp4SpkniEqHkcWF+YOJQ8EcM=";
+    };
+  };
+
+  git = rec {
+    version = src.shortRev;
+    src = builtins.fetchGit {
+      url = gitUrl;
+      ref = gitBranch;
+      rev = gitCommit;
+    };
+  };
+
+  source = if (useGit) then git else release;
+
+in
+
+stdenv.mkDerivation {
+  pname = "tacuda";
+  inherit (source) src version;
+
+  enableParallelBuilding = true;
+  separateDebugInfo = true;
+
+  nativeBuildInputs = [
+    autoreconfHook
+    automake
+    autoconf
+    libtool
+    gnumake
+  ];
+
+  patches = [ ./fix_config.patch ];
+
+  configureFlags = [ "--with-cuda-include=${cudaPackages.cudatoolkit}/include" ];
+
+  buildInputs = [
+    boost
+    cudaPackages.libcublas
+    cudaPackages.cuda_cudart
+  ];
+
+}

pkgs/tacuda/fix_config.patch

@@ -0,0 +1,13 @@
+diff --git a/m4/cuda.m4 b/m4/cuda.m4
+index 23f5c94..8f9b534 100644
+--- a/m4/cuda.m4
++++ b/m4/cuda.m4
+@@ -40,7 +40,7 @@ search_libs="cuda cublas cudart"
+ required_libs=""
+ 
+ m4_foreach([function],
+-           [cuInit,
++           [
+ 	    cublasSgemm,
+             cudaStreamCreate,
+             cudaLaunchKernel,

pkgs/tampi/default.nix

@@ -8,7 +8,6 @@
 , gnumake
 , boost
 , mpi
-, gcc
 , autoreconfHook
 , enableOvni ? true
 , ovni ? null
@@ -41,20 +40,23 @@ let
     };
   };
   source = if (useGit) then git else release;
-in stdenv.mkDerivation rec {
+in stdenv.mkDerivation {
   pname = "tampi";
   inherit (source) src version;
   enableParallelBuilding = true;
   separateDebugInfo = true;
-  buildInputs = [
-    autoreconfHook
-    automake
+
+  nativeBuildInputs = [
     autoconf
-    libtool
+    automake
+    autoreconfHook
     gnumake
+    libtool
+  ];
+
+  buildInputs = [
     boost
     mpi
-    gcc
   ] ++ optional (enableOvni) ovni;
   configureFlags = optional (enableOvni) "--with-ovni=${ovni}";
   dontDisableStatic = true;

pkgs/taopencl/default.nix

@@ -0,0 +1,46 @@
+{
+  stdenv
+, automake
+, autoconf
+, libtool
+, gnumake
+, boost
+, mpi
+, gcc
+, autoreconfHook
+, ocl-icd
+, opencl-headers
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "taopencl";
+  version = finalAttrs.src.shortRev;
+
+  src = builtins.fetchGit {
+    url = "git@gitlab-internal.bsc.es:task-awareness/taopencl/taopencl.git";
+    ref = "master";
+    rev = "c3b7b32ae8fa4af7ceff598532a881f8f1490aaf";
+  };
+
+  enableParallelBuilding = true;
+  separateDebugInfo = true;
+
+  configureFlags = [
+    "--with-opencl-lib=${ocl-icd}/lib"
+    "--with-opencl-include=${opencl-headers}/include"
+  ];
+
+  buildInputs = [
+    autoreconfHook
+    automake
+    autoconf
+    libtool
+    gnumake
+    boost
+    mpi
+    gcc
+  ];
+
+  dontDisableStatic = true;
+  hardeningDisable = [ "all" ];
+})

pkgs/tasycl/default.nix

@@ -0,0 +1,94 @@
+{ stdenv
+, lib
+, withCFlags
+, intelPackages
+, fetchFromGitHub
+, automake
+, autoconf
+, libtool
+, gnumake
+, autoreconfHook
+, boost
+, adaptivecpp ? null
+, useIntel ? true
+
+, useGit ? false
+, gitUrl ? "git@gitlab-internal.bsc.es:task-awareness/tasycl/tasycl.git"
+, gitBranch ? "main"
+, gitCommit ? "78f98dcf60a66e0eaa3b4ebcf55be076bec64825"
+}:
+
+assert (useIntel || adaptivecpp != null);
+
+let
+  variant = if useIntel then "intel" else "acpp";
+
+  syclStdenv =
+    if useIntel then
+      # If we don't set optimization level, separateDebugInfo sets ggdb and
+      # intel disables all optimizations
+      withCFlags ["-O3"] intelPackages.stdenv
+    else
+      withCFlags [ "-L${adaptivecpp}/lib" "-lacpp-rt" "-I${adaptivecpp}/include" ] stdenv
+  ;
+
+  release = rec {
+    version = "2.1.0";
+    src = fetchFromGitHub {
+      owner = "bsc-pm";
+      repo = "tasycl";
+      rev = version;
+      hash = "sha256-0kXnb0lHeQNHR27GTLbJ8xbiICLU8k2+FqEnnFSrzzo=";
+    };
+  };
+
+  git = rec {
+    version = src.shortRev;
+    src = builtins.fetchGit {
+      url = gitUrl;
+      ref = gitBranch;
+      rev = gitCommit;
+    };
+  };
+
+  source = if (useGit) then git else release;
+
+  isOldRelease = (!useGit && (builtins.compareVersions source.version "2.0.0" <= 0));
+
+in
+
+assert !isOldRelease || useIntel; # old releases only work with intel
+
+syclStdenv.mkDerivation {
+  pname = "tasycl";
+  inherit (source) src version;
+
+  enableParallelBuilding = true;
+  separateDebugInfo = true;
+
+  nativeBuildInputs = [
+    autoreconfHook
+    automake
+    autoconf
+    libtool
+    gnumake
+  ];
+
+  buildInputs = [
+    boost
+  ];
+
+  # only needed for release versions prior or equal to 2.0.0
+  configureFlags = lib.optionals isOldRelease [ "--with-sycl-include=${intelPackages.icx.cc}/include/sycl" ];
+
+  # add symlinks so we can explicitly link with tasycl-intel / tasycl-acpp
+  postInstall = ''
+    pushd $out/lib
+    for i in libtasycl* ; do
+      ln -s "$i" "''\${i/tasycl/tasycl-${variant}}"
+    done
+    popd
+  '';
+
+  hardeningDisable = [ "all" ];
+}

test/compilers/hello-sycl.nix

@@ -0,0 +1,55 @@
+{ intelPackages,  writeText, strace }:
+
+let
+  stdenv = intelPackages.stdenv;
+  hello_sycl = writeText "hello.cpp" ''
+    #include <sycl/sycl.hpp>
+
+    class hello_world;
+
+    int main(int argc, char** argv) try {
+        auto device_selector = sycl::default_selector_v;
+
+        sycl::queue queue(device_selector);
+
+        std::cout << "Running on: "
+                  << queue.get_device().get_info<sycl::info::device::name>()
+                  << std::endl;
+
+        queue.submit([&] (sycl::handler& cgh) {
+            auto os = sycl::stream{128, 128, cgh};
+            cgh.single_task<hello_world>([=]() {
+                os << "Hello World! (on device)\n";
+            });
+        });
+
+        return 0;
+    } catch (sycl::exception &e) {
+        std::cout << "SYCL exception: " << e.what() << std::endl;
+        return 0; // we excpect to fail since no devices should be available;
+    }
+  '';
+in
+
+stdenv.mkDerivation {
+  version = "0.0.1";
+  name = "hello-sycl";
+  buildInputs = [ stdenv strace ];
+  src = hello_sycl;
+  dontUnpack = true;
+  dontConfigure = true;
+  NIX_DEBUG = 0;
+  buildPhase = ''
+    cp $src hello.cpp
+    set -x
+    echo CXX=$CXX
+    command -v $CXX
+    $CXX -fsycl hello.cpp -o hello
+    ./hello
+    set +x
+  '';
+
+  installPhase = ''
+    touch $out
+  '';
+}

test/compilers/icpx-ompss2.nix

@@ -0,0 +1,75 @@
+{ writeText, intelPackages, nodes, nosv, clangOmpss2Nodes, strace }:
+
+let
+  hello_cpp = writeText "hello.cpp" ''
+    #include <cstdio>
+    #include <sycl/sycl.hpp>
+
+    int main(int argc, char** argv) try {
+        sycl::queue queue;
+
+        std::cout << "Running on: "
+                  << queue.get_device().get_info<sycl::info::device::name>()
+                  << std::endl;
+
+        #pragma oss task
+        queue.submit([&] (sycl::handler& cgh) {
+            auto os = sycl::stream{128, 128, cgh};
+            cgh.single_task<class hello_world>([=]() {
+                os << "Hello World! (on device)\n";
+            });
+        }).wait();
+
+        return 0;
+    } catch (sycl::exception &e) {
+        std::cout << "SYCL exception: " << e.what() << std::endl;
+        return 0; // we expect to fail since no devices should be available;
+    }
+
+  '';
+in
+
+intelPackages.stdenv.mkDerivation {
+  version = "0.0.1";
+  name = "hello-syclompss";
+
+  src = hello_cpp;
+
+  nativeBuildInputs = [
+    strace
+    nodes
+    nosv
+  ];
+
+  dontUnpack = true;
+  dontConfigure = true;
+
+  # NODES requires access to /sys/devices to request NUMA information. It will
+  # fail to run otherwise, so we disable the sandbox for this test.
+  __noChroot = true;
+
+  env.NODES_HOME = nodes;
+
+  NIX_DEBUG = 0;
+  buildPhase = ''
+    cp $src hello.cpp
+    set -x
+    echo CXX=$CXX
+    echo NODES_HOME=$NODES_HOME
+    command -v $CXX
+
+    icpx -Wno-deprecated-declarations -fsycl \
+        -fsycl-host-compiler=${clangOmpss2Nodes.forIcpx}/bin/clang++ \
+        -fsycl-host-compiler-options='-Wno-deprecated-declarations -fompss-2=libnodes' \
+        -lnodes -lnosv \
+        $NODES_HOME/lib/nodes-main-wrapper.o \
+        hello.cpp -o hello
+
+    ./hello
+    set +x
+  '';
+
+  installPhase = ''
+    touch $out
+  '';
+}