{ config, lib, pkgs, modulesPath, ... }:

{
  imports = [
    "${modulesPath}/installer/sd-card/sd-image.nix"
  ];

  # No need, Lagarto OX has support for rv64gc.
  #nixpkgs.crossSystem = {
  #  system = "riscv64-linux";
  #  gcc.arch = "rv64imafd";
  #  gcc.tune = "rv64imafd";
  #};

  #boot.kernelPackages = pkgs.linuxPackages_latest;
  boot = {
    kernelPatches = [
      {
        name = assert false; "sbi-early-console";
        patch = null;
        extraConfig =
        # Early console via SBI
        ''
          RISCV_SBI y
          RISCV_SBI_V01 y
          SERIAL_EARLYCON y
          SERIAL_EARLYCON_RISCV_SBI y
          HVC_DRIVER y
          HVC_RISCV_SBI y
        ''
        # Allows regions of persistent memory to be described in the device-tree.
        + ''
          OF_PMEM y
        ''
        # Allow you to use a contiguous range of reserved memory as one or more
        # persistent block devices (/dev/pmem0)
        + ''
          LIBNVDIMM y
          BLK_DEV_PMEM y
        ''
        ;
      }
    ];

    initrd = {
      # Avoid zstd as we don't have the tools in "cucu" machine
      compressor = "gzip";
      kernelModules = [ ];
    };

    loader = {
      grub.enable = false;
      generic-extlinux-compatible.enable = true;
    };
  };

  # No network
  services.openssh.enable = false;

  # Run getty on /dev/console and restartt until it works
  systemd.services."serial-getty@console" = {
    enable = true;
    wantedBy = [ "getty.target" ]; # to start at boot
    serviceConfig.Restart = "always";
  };

  # Disable hvc0 as it is racing for the same console
  systemd.services."serial-getty@hvc0" = {
    enable = lib.mkForce false;
    wantedBy = lib.mkForce [ ];
  };

  sdImage = {
    # The image will be loaded as-is in memory, so no compression
    compressImage = false;
    imageName = "rootfs.img";
    # Not needed for now
    expandOnBoot = false;
    populateFirmwareCommands = "";
    populateRootCommands = ''
      mkdir -p ./files/boot
      ${config.boot.loader.generic-extlinux-compatible.populateCmd} \
        -c ${config.system.build.toplevel} \
        -d ./files/boot
    '';
  };

  nixpkgs.overlays = [ (final: prev: {
    ox-dtb = prev.runCommand "ox.dtb" {
      nativeBuildInputs = [ prev.buildPackages.dtc ];
    } "dtc -O dtb -o $out ${./ox-plic.dts}";

    uboot = prev.ubootQemuRiscv64Smode.override {
      filesToInstall = [ "u-boot.bin" "u-boot-nodtb.bin" ];
      version = "2023.07.02-print-cpu-probe";
      src = builtins.fetchGit {
        url = "file:///home/Computational/rarias/riscv/u-boot";
        rev = "b0868e84c392daadcaf611f92209d0c82203386f";
      };
      #patches = [ ./u-boot-debug.patch ];
      extraConfig = ''
        CONFIG_RISCV_ISA_C=n
        CONFIG_REQUIRE_SERIAL_CONSOLE=n
        CONFIG_SERIAL=y
        CONFIG_SERIAL_PUTS=y
        CONFIG_SHOW_BOOT_PROGRESS=y
        CONFIG_SHOW_REGS=y
        CONFIG_LIBCOMMON_SUPPORT=y
        CONFIG_SERIAL_SEARCH_ALL=n
        CONFIG_SERIAL_PROBE_ALL=n
        CONFIG_OF_CONTROL=y
        CONFIG_OF_EMBED=y
        CONFIG_OF_HAS_PRIOR_STAGE=y
        CONFIG_BLKMAP=y
        CONFIG_CMD_BLKMAP=y
        CONFIG_SBI_V01=y
        CONFIG_DEBUG_UART=y
        CONFIG_DEBUG_UART_ANNOUNCE=y
        CONFIG_DEBUG_SBI_CONSOLE=y
        CONFIG_SYS_NS16550=n
        CONFIG_SMP=n
        CONFIG_TRACE_EARLY=y
        CONFIG_LOG=y
        CONFIG_LOGLEVEL=9
        CONFIG_LOG_MAX_LEVEL=9
        CONFIG_LOG_DEFAULT_LEVEL=9
      '';
      extraMakeFlags = [
        "KCPPFLAGS=-DLOG_DEBUG"
        #"EXT_DTB=${final.ox-dtb}"
      ];
    };

    uboot-env = let
      init = "${config.system.build.toplevel}/init";
      initrd = "${config.system.build.initialRamdisk}/initrd";
    in prev.runCommand "uboot.txt" {} ''
      cat > $out <<EOF
      # Create pmem of 3 GiB [0x140000000, 0x200000000)
      fdt mknode / pmem@0x140000000
      fdt set /pmem@0x140000000 compatible "pmem-region"
      fdt set /pmem@0x140000000 reg <0x1 0x40000000 0x0 0xc0000000>

      # Reduce memory to 3 GiB [0x80000000, 0x140000000)
      fdt set /memory@80000000  reg <0x0 0x80000000 0x0 0xc0000000>

      # Set kernel options
      setenv bootargs "root=/dev/ram0 loglevel=7 debug rw earlycon=sbi boot.trace console=hvc0 init=${init}"

      EOF

      # Populate the bood commands from the initrd size
      echo "# Boot system" >> $out
      echo "setenv ramdisk_size $(stat --format %s $(readlink -f ${initrd}))" >> $out
      echo 'booti ''${kernel_addr_r} ''${ramdisk_addr_r}:''${ramdisk_size} ''${fdtcontroladdr}' >> $out
    '';

    # Lagarto OX doesn't work with newer versions of OpenSBI (1.3, 1.4), not
    # sure why.
    opensbi = prev.opensbi.overrideAttrs (old: rec {
      version = "1.2"; # ok
      #version = "1.3"; # bad
      #version = "1.4"; # bad
      src = prev.fetchFromGitHub {
        owner = "riscv-software-src";
        repo = "opensbi";
        rev = "v${version}";
        hash = "sha256-Zcl+SE2nySMycV/ozsl4AvGipRsMblA5mt3oVZ81Z44="; #1.2
        #hash = "sha256-Dr16fVUGLYGnGYHkjAyqpJxt8p95F0CJIU9ESGWKGWo="; #1.3
        #hash = "sha256-T8ZeAzjM9aeTXitjE7s+m+jjGGtDo2jK1qO5EuKiVLU="; #1.4
      };
      #NIX_DEBUG=5;
      # Compile dts to dtb form
      nativeBuildInputs = (old.nativeBuildInputs or []) ++ [ prev.buildPackages.dtc ];
      dtsFile = ./ox-plic.dts;
      preBuild = ''
        dtc -O dtb -o ox.dtb $dtsFile
      '';
      makeFlags = [
        "PLATFORM=fpga/ox_alveo"
        #"CONFIG_SBI_ECALL_RFENCE=n"
        #"PLATFORM_RISCV_ISA=rv64imafd" # No compressed instructions
        #"PLATFORM_RISCV_ISA=rv64g" # No compressed instructions
        #"PLATFORM_RISCV_ABI=lp64d"
        "FW_PAYLOAD_PATH=${final.uboot}/u-boot.bin"
        "FW_FDT_PATH=ox.dtb"
      ];
      patches = [ ./ox-alveo-platform-plic.patch ];
    });
#    opensbi = prev.opensbi.overrideAttrs (old: {
#      #NIX_DEBUG=5;
#      # Compile dts to dtb form
#      #nativeBuildInputs = (old.nativeBuildInputs or []) ++ [ prev.buildPackages.dtc ];
#      #preBuild = ''
#      #  dtc -O dtb -o ox.dtb ${./ox.dts}
#      #'';
#      makeFlags = old.makeFlags ++ [
#        "PLATFORM=fpga/sargantana_alveo"
#        #"PLATFORM_RISCV_ISA=rv64imafd" # No compressed instructions
#        "PLATFORM_RISCV_ISA=rv64g" # No compressed instructions
#        #"PLATFORM_RISCV_ABI=lp64d"
#        "FW_PAYLOAD_PATH=${final.uboot}/u-boot-nodtb.bin"
#        #"FW_FDT_PATH=ox.dtb"
#      ];
#      patches = [ ./alveo-uart-sbi-hack.patch ];
#    });
#    opensbi = prev.opensbi.overrideAttrs (old: {
#      makeFlags = old.makeFlags ++ [
#        "PLATFORM=fpga/openpiton"
#        "FW_PAYLOAD_PATH=${final.uboot}/u-boot-nodtb.bin"
#      ];
#      patches = [ ./opensbi-lagarto-hun.patch ];
#    });
  }) ];
}