nixos-riscv/flake.nix

{
  inputs.nixpkgs.url = "github:rodarima/nixpkgs/fix-pkgs-static-gcc-march";
  #inputs.bscpkgs.url = "path:/home/Computational/rarias/bscpkgs";
  inputs.bscpkgs.url = "/home/Computational/rarias/bscpkgs";

  outputs = { self, nixpkgs, bscpkgs, ... }:
  let
    system = "x86_64-linux";
    #overlay = import ./overlay.nix;
    #pkgs = import nixpkgs { inherit system; };
  in {
    #overlay = import ./overlay.nix;
    nixosConfigurations = {
      # The qemu configuration defines a system that runs in the RISC-V
      # architecture, but is build from an x86 host machine.
      qemu = nixpkgs.lib.nixosSystem {
        specialArgs = { inherit self; };
        system = "${system}";
        modules = [
          ./configuration.nix
          ./vm.nix
        ];
      };

      # Same, but disable compressed instructions
      qemu-nc = nixpkgs.lib.nixosSystem {
        specialArgs = { inherit self; };
        system = "${system}";
        modules = [
          ./configuration.nix
          ./vm.nix
          ./no-compressed.nix
        ];
      };

      # FPGA Lagarto Hun CPU
      lagarto-hun = nixpkgs.lib.nixosSystem {
        specialArgs = { inherit self; };
        system = "${system}";
        modules = [
          ./configuration.nix
          ./lagarto-hun.nix
          ./no-compressed.nix
        ];
      };
    };

    # A development shell with QEMU ready to boot the RISC-V system in an x86
    # machine.
    devShells.x86_64-linux.default =
    let
      nixosconf = self.nixosConfigurations.qemu-nc;
      syspkgs = nixosconf.pkgs;
      toplevel = nixosconf.config.system.build.toplevel;
    in syspkgs.mkShell {
      pname = "qemu-shell";
      buildInputs = with syspkgs; [ qemu e2fsprogs ];
      # Here we tell the run script where to find the system
      NIXOS_SYSTEM_TOPLEVEL = toplevel;
      OPENSBI = syspkgs.opensbi-uboot;
    };
    devShells.x86_64-linux.lagarto-hun =
    let
      nixosconf = self.nixosConfigurations.lagarto-hun;
      syspkgs = nixosconf.pkgs;
      build = nixosconf.config.system.build;
    in syspkgs.mkShell {
      pname = "lagarto-hun-shell";
      TOPLEVEL = build.toplevel;
      OPENSBI = syspkgs.opensbi;
      KERNEL = build.kernel;
      INITRD = build.initialRamdisk;
      ROOTFS = build.sdImage;
      UBOOT_ENV = syspkgs.uboot-env;
    };
  };
}