From 9631f4c22331f22f0c79a82d6e0e999fbdff3e36 Mon Sep 17 00:00:00 2001
From: Rodrigo Arias <rodrigo.arias@bsc.es>
Date: Wed, 5 Aug 2020 10:57:05 +0200
Subject: [PATCH] Add slurm 17.11.9-2, builds ok.

---
 bsc/slurm/default.nix | 70 +++++++++++++++++++++++++++++++++++++++++++
 default.nix           |  2 ++
 2 files changed, 72 insertions(+)
 create mode 100644 bsc/slurm/default.nix

diff --git a/bsc/slurm/default.nix b/bsc/slurm/default.nix
new file mode 100644
index 0000000..17beab9
--- /dev/null
+++ b/bsc/slurm/default.nix
@@ -0,0 +1,70 @@
+{ stdenv, fetchFromGitHub, pkgconfig, libtool, curl
+, python, munge, perl, pam, openssl
+, ncurses, libmysqlclient, gtk2, lua, hwloc, numactl
+, readline, freeipmi, libssh2, xorg
+# enable internal X11 support via libssh2
+, enableX11 ? true
+}:
+
+stdenv.mkDerivation rec {
+  name = "slurm-${version}";
+  version = "17.11.9-2";
+
+  # N.B. We use github release tags instead of https://www.schedmd.com/downloads.php
+  # because the latter does not keep older releases.
+  src = fetchFromGitHub {
+    owner = "SchedMD";
+    repo = "slurm";
+    # The release tags use - instead of .
+    rev = "${builtins.replaceStrings ["."] ["-"] name}";
+    sha256 = "1lq4ac6yjai6wh979dciw8v3d99zbd3w36rfh0vpncqm672fg1qy";
+  };
+
+  outputs = [ "out" "dev" ];
+
+  prePatch = stdenv.lib.optional enableX11 ''
+    substituteInPlace src/common/x11_util.c \
+        --replace '"/usr/bin/xauth"' '"${xorg.xauth}/bin/xauth"'
+  '';
+
+  # nixos test fails to start slurmd with 'undefined symbol: slurm_job_preempt_mode'
+  # https://groups.google.com/forum/#!topic/slurm-devel/QHOajQ84_Es
+  # this doesn't fix tests completely at least makes slurmd to launch
+  hardeningDisable = [ "bindnow" ];
+
+  nativeBuildInputs = [ pkgconfig libtool ];
+  buildInputs = [
+    curl python munge perl pam openssl
+      libmysqlclient ncurses gtk2
+      lua hwloc numactl readline freeipmi
+  ] ++ stdenv.lib.optionals enableX11 [ libssh2 xorg.xauth ];
+
+  configureFlags = with stdenv.lib;
+    [ "--with-munge=${munge}"
+      "--with-ssl=${openssl.dev}"
+      "--with-hwloc=${hwloc.dev}"
+      "--with-freeipmi=${freeipmi}"
+      "--sysconfdir=/etc/slurm"
+    ] ++ (optional (gtk2 == null)  "--disable-gtktest")
+      ++ (optional enableX11 "--with-libssh2=${libssh2.dev}");
+
+
+  preConfigure = ''
+    patchShebangs ./doc/html/shtml2html.py
+    patchShebangs ./doc/man/man2html.py
+  '';
+
+  postInstall = ''
+    rm -f $out/lib/*.la $out/lib/slurm/*.la
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with stdenv.lib; {
+    homepage = http://www.schedmd.com/;
+    description = "Simple Linux Utility for Resource Management";
+    platforms = platforms.linux;
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ jagajaga markuskowa ];
+  };
+}
diff --git a/default.nix b/default.nix
index ef392d7..0fed8c4 100644
--- a/default.nix
+++ b/default.nix
@@ -66,6 +66,8 @@ let
     intel-license = callPackage bsc/intel-compiler/license.nix {
     };
 
+    slurm17 = callPackage ./bsc/slurm/default.nix { };
+
     fftw = callPackage ./bsc/fftw/default.nix {
       mpi = mpi;
     };