{ lib
, llvmPackages
, ninja
, cmake
, hwloc
, ocl-icd
, opencl-headers
, getconf
, pkg-config
, spirv-llvm-translator
, spirv-tools
, libxml2  # required for statically linked llvm
, python3
, writableTmpDirAsHomeHook

, fetchFromGitHub

, useGit ? false
, gitUrl ? "git@gitlab-internal.bsc.es:task-awareness/pocl/pocl.git"
, gitBranch ? "new-device"
, gitCommit ? "dd10c2221b31223cbb796182df6a07f11c7541f5"

, staticLLVM ? true
, enableICD ? true
, enableSPIRV ? true
, enableHWLOC ? true
, enableRemoteServer ? false
, enableRemoteClient ? false
, enableDistroVariants ? false

, lttng-ust
, enableLTTNG ? false

, tbb
, enableTBB ? false

, nosv ? null
, ovni ? null
, enableNOSV ? useGit
, enableOVNI ? useGit

, buildPackages
, nix-update-script
}:

let

  release = rec {
    version = "7.1";
    src = fetchFromGitHub {
      owner = "pocl";
      repo = "pocl";
      tag = "v${version}";
      hash = "sha256-bS6vTIjLO7YLs7qYLKW0cYYbEJ/hRS/+IjjAKbkj8ac=";
    };
  };

  git = rec {
    version = src.shortRev;
    src = builtins.fetchGit {
      url = gitUrl;
      ref = gitBranch;
      rev = gitCommit;
    };
  };

  source = if (useGit) then git else release;

  stdenv = llvmPackages.stdenv;

  buildLlvmPackages = buildPackages.llvmPackages;

  isCross = stdenv.hostPlatform != stdenv.buildPlatform;

  featureList = lib.concatStringsSep "+" (
    (lib.optionals enableICD ["icd"]) ++
    (lib.optionals enableNOSV ["nosv"]) ++
    (lib.optionals enableOVNI ["ovni"]) ++
    (lib.optionals enableSPIRV ["spirv"]) ++
    (lib.optionals enableTBB ["tbb"]) ++
    (lib.optionals enableRemoteClient ["server"]) ++
    (lib.optionals enableRemoteServer ["client"])
  );
in

stdenv.mkDerivation (finalAttrs: {
  pname = "pocl";
  version = featureList + "-" + source.version;
  inherit (source) src;

  patches = lib.optionals useGit [
    ./0001-cmake-use-clang-from-cmake-variable.patch
    ./0001-cmake-do-not-use-suffix.patch
    ./0001-cmake-native-build-tools.patch
  ];

  cmakeFlags = [
    (lib.cmakeOptionType "filepath" "WITH_LLVM_CONFIG"    (lib.getExe' buildLlvmPackages.llvm.dev     "llvm-config"))
    (lib.cmakeOptionType "filepath" "CLANG"               (lib.getExe' buildLlvmPackages.clangUseLLVM "clang"))
    (lib.cmakeOptionType "filepath" "CLANGXX"             (lib.getExe' buildLlvmPackages.clangUseLLVM "clang++"))
    (lib.cmakeOptionType "path"     "CLANG_RESOURCE_DIR" "${llvmPackages.stdenv.cc}/resource-root")

    (lib.cmakeBool "ENABLE_TESTS" finalAttrs.finalPackage.doCheck)

    (lib.cmakeBool "ENABLE_RELOCATION"    true)
    (lib.cmakeBool "ENABLE_POCL_BUILDING"   true)
    (lib.cmakeBool "POCL_ICD_ABSOLUTE_PATH" true)

    (lib.cmakeBool "ENABLE_TBB_DEVICE" enableTBB)
    (lib.cmakeBool "ENABLE_ICD"        enableICD)
    (lib.cmakeBool "ENABLE_HWLOC"      enableHWLOC)
    (lib.cmakeBool "ENABLE_LTTNG"      enableLTTNG)

    (lib.cmakeBool "ENABLE_REMOTE_CLIENT" enableRemoteClient)
    (lib.cmakeBool "ENABLE_REMOTE_SERVER" enableRemoteServer)

    # avoid the runtime linker pulling in a different llvm e.g. from graphics drivers
    (lib.cmakeBool "STATIC_LLVM" staticLLVM)
  ] ++ lib.optionals (enableNOSV || enableOVNI) [
    (lib.cmakeBool "ENABLE_NOSV"       enableNOSV)
    (lib.cmakeBool "ENABLE_OVNI"       enableOVNI)
  ] ++ lib.optionals (!isCross && enableDistroVariants) [
    (lib.cmakeFeature "KERNELLIB_HOST_CPU_VARIANTS" "distro") # TODO: check if we can do it when cross compiling
  ] ++ lib.optionals isCross [
    (lib.cmakeFeature "CMAKE_SYSTEM_NAME" "Linux")
    (lib.cmakeFeature "CMAKE_FIND_ROOT_PATH_MODE_PROGRAM" "NEVER")
    (lib.cmakeFeature "CMAKE_FIND_ROOT_PATH_MODE_LIBRARY" "ONLY")
    (lib.cmakeFeature "CMAKE_FIND_ROOT_PATH_MODE_INCLUDE" "ONLY")
    (lib.cmakeFeature "CMAKE_FIND_ROOT_PATH_MODE_PACKAGE" "ONLY")
  ] ++ lib.optionals stdenv.hostPlatform.isRiscV [
    (lib.cmakeFeature "LLC_TRIPLE"       "riscv64-unknown-linux-gnu")
    (lib.cmakeFeature "LLC_HOST_CPU"     "rv64g")
    (lib.cmakeFeature "CLANG_MARCH_FLAG" "-march=")
  ];

  # Fixes error: ld: cannot find -lgcc / -lgcc_s when linking from libpocl on
  # host
  preConfigure = ''
    cmakeFlagsArray+=(
      -DEXTRA_HOST_LD_FLAGS="${lib.escapeShellArg (builtins.readFile "${stdenv.cc}/nix-support/cc-ldflags")}"
      -DEXTRA_KERNEL_FLAGS="${lib.escapeShellArg (builtins.readFile "${stdenv.cc}/nix-support/cc-ldflags")}"
    )
  '' + lib.optionalString stdenv.hostPlatform.isRiscV ''
     cmakeFlagsArray+=(
      -DEXTRA_HOST_LLC_FLAGS=${lib.escapeShellArg ([
        "-march=rv64g"
        "-mcpu=sifive-u74"
      ])}
      -DEXTRA_HOST_CLANG_FLAGS=${lib.escapeShellArg ([
        "-mabi=lp64d"
        "-march=rv64g"
        "-mcpu=sifive-u74"
        "-mtune=sifive-7-series"
      ])}
    )
  '';

  nativeBuildInputs = [
    cmake
    getconf
    ninja
    pkg-config
    python3
  ];

  buildInputs = [
    opencl-headers
    llvmPackages.libclang
    llvmPackages.llvm
  ] ++ lib.optionals staticLLVM [ libxml2 ]
  ++ lib.optionals enableNOSV   [ nosv ]
  ++ lib.optionals enableOVNI   [ ovni ]
  ++ lib.optionals enableHWLOC  [ hwloc ]
  ++ lib.optionals enableTBB    [ tbb ]
  ++ lib.optionals enableICD    [ ocl-icd ]
  ++ lib.optionals enableLTTNG  [ lttng-ust ]
  ++ lib.optionals enableSPIRV  [
    (spirv-llvm-translator.override { inherit (llvmPackages) llvm; })
    spirv-tools
  ];

  nativeInstallCheckInputs = [
    writableTmpDirAsHomeHook
  ];

  doInstallCheck = true;

  installCheckPhase = lib.optionalString enableICD ''
    runHook preInstallCheck

    export OCL_ICD_VENDORS=$out/etc/OpenCL/vendors
    $out/bin/poclcc -o poclcc.cl.pocl $src/examples/poclcc/poclcc.cl

    runHook postInstallCheck
  '';

  setupHook = ./setup-hook.sh;

  passthru = {
    updateScript = nix-update-script { };
    git = finalAttrs.finalPackage.override { useGit = true; };
    test = finalAttrs.finalPackage.overrideAttrs { doCheck = true; };
  };

  requiredSystemFeatures = lib.optionals (finalAttrs.finalPackage.doCheck && enableHWLOC) [ "sys-devices" ];

  preCheck = ''
    export POCL_DEBUG=error,warn
    export NIX_DEBUG=1
  '';

  propagatedBuildInputs = [ stdenv.cc.cc ];

  meta = with lib; {
    description = "A portable open source (MIT-licensed) implementation of the OpenCL standard";
    homepage = "http://portablecl.org";
    license = licenses.mit;
    maintainers = with maintainers; [
      leixb
      jansol
      xddxdd
      bsc.maintainers.leixb
    ];
    platforms = platforms.linux ++ platforms.darwin;
  };
})