From 7bc6fc9b02c28b8430d967d9a68aa803ca99c8bd Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Aleix=20Bon=C3=A9?= <aleix.boneribo@bsc.es>
Date: Mon, 3 Nov 2025 10:41:57 +0100
Subject: [PATCH] Add pertalde

---
 overlay.nix               |  1 +
 pkgs/pertalde/default.nix | 47 +++++++++++++++++++++++++++++++++++++++
 2 files changed, 48 insertions(+)
 create mode 100644 pkgs/pertalde/default.nix

diff --git a/overlay.nix b/overlay.nix
index 4e34a35..2120039 100644
--- a/overlay.nix
+++ b/overlay.nix
@@ -53,6 +53,7 @@ let
     ovni = callPackage ./pkgs/ovni/default.nix { };
     ovniGit = final.ovni.override { useGit = true; };
     paraverKernel = callPackage ./pkgs/paraver/kernel.nix { };
+    pertalde = callPackage ./pkgs/pertalde/default.nix { };
     prometheus-slurm-exporter = prev.callPackage ./pkgs/slurm-exporter/default.nix { };
     #pscom = callPackage ./pkgs/parastation/pscom.nix { }; # Unmaintaned
     #psmpi = callPackage ./pkgs/parastation/psmpi.nix { }; # Unmaintaned
diff --git a/pkgs/pertalde/default.nix b/pkgs/pertalde/default.nix
new file mode 100644
index 0000000..07c6f0b
--- /dev/null
+++ b/pkgs/pertalde/default.nix
@@ -0,0 +1,47 @@
+{
+  lib,
+  python3,
+  fetchPypi,
+  cargo,
+  rustPlatform,
+  rustc,
+}:
+
+let
+  pname = "pertalde";
+  version = "0.1.4";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-KdS5yNYR+8z81hMBTl9oNiLi17cVLyoZBNNR88T/gOY=";
+  };
+in
+python3.pkgs.buildPythonApplication {
+  inherit pname version src;
+  pyproject = true;
+  strictDeps = true;
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit src;
+    name = "${pname}-${version}";
+    hash = "sha256-dQ8EKlYZq+Urtb+0zxRi/Vh/ormIGCNKHy/9entyb7g=";
+  };
+
+  # error[E0554]: `#![feature]` may not be used on the stable release channel
+  env.RUSTC_BOOTSTRAP = true;
+
+  build-system = [
+    cargo
+    rustPlatform.cargoSetupHook
+    rustPlatform.maturinBuildHook
+    rustc
+  ];
+
+  meta = {
+    description = "Some command-line utilities on paraver traces";
+    homepage = "https://pypi.org/project/pertalde/";
+    license = lib.licenses.gpl3Only;
+    maintainers = with lib.maintainers.bsc; [ abonerib ];
+    mainProgram = "ptd";
+  };
+}