{ ... }:
let
  nosv = <nosv>;
  ovni = <ovni>;
  nodes = <nodes>;
  nanos6 = <nanos6>;

  requiredSystemFeatures = [ "sys-devices" ];

  getVersion = x: toString (x.shortRev or x.dirtyShortRev or x.lastModified or "master");

  pkgs = (
    import <bscpkgs> {
      overlays = [
        (final: prev: {
          nosv = prev.nosv.overrideAttrs (old: {
            src = nosv;
            version = getVersion nosv;

            doCheck = true;
            inherit requiredSystemFeatures;
          });

          ovni = prev.ovni.overrideAttrs (old: {
            src = ovni;
            version = getVersion ovni;

            doCheck = true;
          });

          nanos6 = prev.nanos6.overrideAttrs (old: {
            src = nanos6;
            version = getVersion nanos6;

            doCheck = true;
          });

          nodes = prev.nodes.overrideAttrs (old: {
            src = nodes;
            version = getVersion nodes;

            doCheck = true;
            inherit requiredSystemFeatures;
          });
        })
      ];
    }
  );

  tarballs = {
    nosv = pkgs.releaseTools.sourceTarball {
      name = "nosv-tarball";
      inherit (pkgs.nosv) src version;
      preAutoconf = "sed -i 's/AC_MSG_RESULT/_AS_ECHO/ configure.ac'";
    };
  };
in
{
  pkgs = {
    inherit (pkgs)
      nosv
      ovni
      nodes
      nanos6
      ;
  };

  inherit tarballs;

  coverage.nosv = pkgs.releaseTools.coverageAnalysis {
    name = "nosv-coverage";
    src = tarballs.nosv;
    lcovFilter = [ "*/tests/*" ];
  };

  sanitized.nosv = pkgs.nosv.overrideAttrs (old: {
    configureFlags = [
      "--with-asan "
      "--with-ubsan"
    ];
    # CFLAGS = "-Werror";
  });
}